% V20210224 - 11.14 Spinner Customization

INCLUDE "GW.bas"

% Create a page.
p = GW_NEW_PAGE()

% Prepare title bar string.
Title$ = GW_ADD_BAR_TITLE$("Spinner Customization")

% Add title to page.
GW_ADD_TITLEBAR(p, Title$)

% Add descriptive text.
GW_ADD_TEXT(p, "Click a button to show a spinner:")

% Create a notext light mode spinner.
GW_USE_THEME_CUSTO_ONCE("color=a")
spin_nt_l = GW_ADD_SPINNER(p, "")

% Create a notext dark mode spinner.
GW_USE_THEME_CUSTO_ONCE("color=b")
spin_nt_d = GW_ADD_SPINNER(p, "")

% Create a light mode spinner with text.
spin_t_l = GW_ADD_SPINNER(p, "Loading...")

% Create a dark mode spinner with text.
GW_USE_THEME_CUSTO_ONCE("color=b")
spin_t_d = GW_ADD_SPINNER(p, "Please be patient.")

% Add  buttons to activate each spinner.
GW_ADD_BUTTON(p, "No text, light mode", "nt_l")

GW_USE_THEME_CUSTO_ONCE("color=b")
GW_ADD_BUTTON(p, "No text, dark mode", "nt_d")

GW_ADD_BUTTON(p, "With text, light mode", "t_l")

GW_USE_THEME_CUSTO_ONCE("color=b")
GW_ADD_BUTTON(p, "With text, dark mode", "t_d")

% Add a button to hide the currently displayed spinner.
GW_USE_THEME_CUSTO_ONCE("style='background:red;color:white'")
GW_ADD_BUTTON(p, "Hide the spinner", "hide")

% Now show the page.
GW_RENDER(p)

DO   % Wait for user action.
 r$ = GW_WAIT_ACTION$()

 % Parse user action.
 SW.BEGIN r$

 % Show spinner notext light.
 SW.CASE "nt_l"
  GW_SHOW_SPINNER(spin_nt_l)
  SW.BREAK

 % Show spinner notext dark.
 SW.CASE "nt_d"
  GW_SHOW_SPINNER(spin_nt_d)
  SW.BREAK

 % Show spinner w/ text light.
 SW.CASE "t_l"
  GW_SHOW_SPINNER(spin_t_l)
  SW.BREAK

 % Show spinner w/ text dark.
 SW.CASE "t_d"
  GW_SHOW_SPINNER(spin_t_d)
  SW.BREAK

 % Hide spinner.
 SW.CASE "hide"
  GW_HIDE_SPINNER()
  SW.BREAK

 SW.END

% End when BACK key is pressed.
UNTIL r$ = "BACK"

END "End of Spinner Customization example."